A] addtimer

form
    addtimer <ticks>, "<NPC object name>::<label>";

    ticks: 지연 시간, 단위는 ms
    NPC object name: Npc 이름(별칭 # 포함)
    label: Npc objcet name이 가지고 있는 라벨명

func
    Npc와 대화중인 PC에게 시간을 부여하여, 시간이 되면 지정한 Npc의 라벨이 PC에게 동작하게 한다.

return 
    없음

related
    deltimer "<NPC object name>::<event label>";
    addtimercount <ticks>, "<NPC object name>::<event label>";

info
    deltimer로 부여 받은 지연 이벤트를 삭제할 수 있고, addtimercount로 지연 시간을 +- 할 수 있다
    시간을 부여 받은 PC가 로그아웃 또는 특정 모션을 취할 때는 이벤트가 소멸된다
    캐릭터당 받을 수 있는 이벤트 수(32개)를 넘길 때는 동작하지 않는다
    대화 중인 PC에게만 사용 가능한 구문이다(주체가 PC일 때만)

Ex Code
prontera,100,100,3    script    셔틀 도우미    100,{
    if ( quest )
    {
        if (countitem(519) >= 3 && countitem(580) >= 1 && Zeny >= 500) goto Success;
        mes "[셔틀 도우미]";
        mes "뭐해? 퍼득 안달려가?";
        next;
        menu "넹넹.",End,"시간이 부족해요(굽신굽신)",-;
            addtimercount 120000,"셔틀 도우미::Failure";
            mes "[셔틀 도우미]";
            mes "그래?";
            mes "좋아, 난 킹왕짱 착하니까 지금부터 2분 줄게.";
            next;
            mes "[셔틀 도우미]";
            mes "뭐해? 퍼득 사와.";
            close;
    }
    mes "[셔틀 도우미]";
    mes "너님은 1,000원 가지고 1분 안에 빵 하나와 우유 3개를 사고, 거스름돈 500원을 가져와야해.";
    mes "You are copy?";
    next;
    menu "ㄲㅈ.",-,"넹.",-;
        addtimer 60000,"셔틀 도우미::Failure";
        set Zeny,Zeny+1000;
        set quest,1;
        mes "[셔틀 도우미]";
        mes "1분 줄게 퍼득 달려가.";
        close;

Success:
    deltimer "셔틀 도우미::Failure";
    set Zeny,Zeny-500;
    delitem 519,3;
    delitem 580,1;
    set quest,0;
    mes "[셔틀 도우미]";
    mes "오오. 너님은 셔틀에 재능이 있네.";
    mes "앞으로도 자주 시키겠어.";
    close;

Failure:
    mes "[셔틀 도우미]";
    mes "너님 이것도 못하네.";
    mes "벌 좀 받아야 겠어. ㅉㅉ.";
    close2;
    percentheal -100,0;
    end;

End:
    close;
}

덧글

[하얀요괴]

아이루나에서 블로그 차렸다는 글을보고옵니다
엔피씨가 참 착하군요 1000원이라는 귀한돈을 내주다니.

[패드곰]

절대 서버에 적용하면 안됩니다 ㅋ

[으놔]

로그아웃하면 타이머가 다 날아가니까 1000원 받고
재접하고 그냥 심심할때 반납하면 죽지 않고도 500원을 더 벌 수 있다!
ㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋㅋ

[패드곰]

어디까지나 구문 예제 ㅋㅋㅋㅋ
보증따위 ㅋㅋㅋㅋ